Appuyez sur Entrée pour voir vos résultats ou Echap pour annuler.

  0 commentaire

Identifiants uniques et liens hypertextes automatiques pour les documents juridiques en ligne
La référence neutre a un "frère" Internet

[mise à jour au 13 avril 2010 : une deuxième version du projet URN:LEX a été publiée, et commentée, toujours sur le blog Legal Informatics]

Signalée par le Legal Informatics Blog et disponible sur le site de l’IETF [1] : URN LEX Namespace for Sources of Law, une proposition de standard Internet faite notamment par l’ITTIG (Italie) [2] et le Legal Information Institute (LII) [3] de la Cornell Law School (Etats-Unis) et datée du 30 octobre 2009.

De quoi s’agit il ? Réponse, extraite du premier paragraphe du document lui-même (traduction rapide par GG et nos soins) :

« Le but de l’espace de nommage "LEX" consiste à attribuer un identifiant unique, dans un format standardisé, à des documents qui sont des sources de droit. L’identifiant est conçu pour que sa construction ne dépende que des caractéristiques du document lui-même et soit donc indépendante de la disponibilité du document en ligne, de sa localisation physique et de son mode d’accès.
"Sources du droit" signifie tout document juridique appartenant au domaine de la législation (y compris les projets et propositions de loi), de la réglementation, de la jurisprudence et des actes administratifs. Cet identifiant sera utilisé comme un moyen de représenter les références (et plus généralement, tout type de relation) entre les différentes sources de droit.
Dans un environnement en ligne, avec des ressources réparties entre les différents éditeurs web, des noms de ressources uniformes permettent de simplifier l’interconnexion globale des documents juridiques par le biais de liens hypertextes automatiques. »

Ce serait l’équivalent en ligne, sous forme de lien hypertexte (URL), de la référence neutre. 37 pages d’un travail scientifique très sérieux et détaillé. Une proposition révolutionnaire qui faciliterait et la recherche en ligne et le droit comparé [4].

Voici la syntaxe — autrement dit la structure et comment on l’écrit — de l’espace de nommage LEX :

*-------------------------------------------------------------------
* General Structure of a Uniform Resource Name (URN)
* NID = namespace
* NSS = specific name
*-------------------------------------------------------------------
<URN> ::= "urn:"<NID>":"<NSS>

*-------------------------------------------------------------------
* Structure of a Uniform Resource Name (URN) of the "lex" namespace
*-------------------------------------------------------------------
<NID> ::= "lex"

<URN> ::= "urn:lex:"<NSS-lex>

*-------------------------------------------------------------------
* Structure of a "lex" specific name
*-------------------------------------------------------------------
<NSS-lex> ::= <country>":"<local-name>

*-------------------------------------------------------------------
* Structure of the <country> element
*-------------------------------------------------------------------
<country> ::= <country-code>[";"<country-unit>]*

   <country-code> ::= <lowercase>{2,4}

   <country-unit> ::= <alfanum>[<normal>]*

*-------------------------------------------------------------------
* Structure of the <national-name> element
*-------------------------------------------------------------------
<national-name> ::= <work>["@"<expression>]?["$"<manifestation>]?

*-------------------------------------------------------------------
* Structure of the <work> element
*-------------------------------------------------------------------
<work> ::= <authority>":"<measure>":"<details>[":"<annex>]*

*-------------------------------------------------------------------
* Structure of the <authority> element
*-------------------------------------------------------------------
<authority> ::= <issuer>["+"<issuer>]*

   <issuer> ::= (<institution>[";"<body>]*[";"<function>]*) | <office>

      <institution> ::= <alfanum>[<normal>]*

      <body> ::= <alfanum>[<normal>]*

      <function> ::= <alfanum>[<normal>]*

      <office> ::= <alfanum>[<normal>]*

*-------------------------------------------------------------------
* Structure of the <measure> element
*-------------------------------------------------------------------
<measure> ::= <measure-type>[";"<specification>]*

   <measure-type> ::= <alfanum>[<normal>]*

   <specification> ::= <alfanum>[<normal>]*

*-------------------------------------------------------------------
* Structure of the <details> element
*-------------------------------------------------------------------
<details>  ::=  (<dates>|<period>)";"<numbers>

   <dates>  ::=  <date>[","<date>]*
"lex"
   <period>  ::= <alfanum>[<normal>]*

   <numbers> ::= (<document-id>[","<document-id>]*)|<number-lex>

      <document-id> ::= <alfanum>[<normal>|<other>]*

      <number-lex> ::= "lex-"<digit>+

*-------------------------------------------------------------------
* Structure of the <annex> element
*-------------------------------------------------------------------
<annex> ::= <annex-id>[";"<specification>]*

   <annex-id> ::= <alfanum>[<normal>]*

*-------------------------------------------------------------------
* Structure of the <expression> element
*-------------------------------------------------------------------

<expression> ::= <version>[":"<language>]?

*-------------------------------------------------------------------
* Structure of the <version> element
*-------------------------------------------------------------------

<version> ::= (<amendment-date>|<specification>)
              [";"(<event-date>|<event>)]*

   <amendment-date> ::= <date>

   <event-date> ::= <date>

   <event> ::= <alfanum>[<normal>]*

*-------------------------------------------------------------------
* Structure of the <language> element
*-------------------------------------------------------------------

<language> ::= <lowercase>{2,3}

*-------------------------------------------------------------------
* Structure of the <manifestation> element
*-------------------------------------------------------------------
<manifestation> ::= <format>[";"<specification>"]*
                    ":"<editor>[";"<specification>"]*
                    [":"<component>[";"<specification>]*]?
                    [":"<feature>[";"<specification>]*]?

<format> ::= <alfanum>[<normal>|"-"]*

<editor> ::= <alfanum>[<normal>|"-"]*

<component> ::= <alfanum>[<normal>|"-"]*

<feature> ::= <alfanum>[<normal>|"-"]*

*-------------------------------------------------------------------
* Structure of the date
*-------------------------------------------------------------------
<date> ::= <year>"-"<month>"-"<day>

   <year>  ::= <digit>{4}
   <month> ::= <digit>{2}
   <day>   ::= <digit>{2}

*-------------------------------------------------------------------
* Allowed characters
*-------------------------------------------------------------------
<allowed-lex> ::= <normal> | <other> | <reserved> | <future>

   <normal> ::= <alfanum> | "."

      <alfanum> ::= <lowercase> | <digit> | <encoded>

      <lowercase> ::= "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" |
                      "i" | "j" | "k" | "l" | "m" | "n" | "o" | "p" |
                      "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" |
                      "y" | "z"

      <digit>     ::= "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" |
                      "8" | "9"

      <encoded>   ::= ("%" (<digit> | <hex-let>)){1,6}

      <hex-let>   ::= "a" | "b" | "c" | "d" | "e" | "f"

   <other>    ::= "-" | "_" | "'" | "=" | "(" | ")"

   <reserved> ::= ":" | "@" | "$" | "+" | ";" | ","

   <future>   ::= "*" |  "!"

Emmanuel Barthe
documentaliste juridique en ligne et en papier — au choix du meilleur des deux :-)

Notes

[1] L’Internet Engineering Task Force (IETF) est un groupe informel, international, ouvert à tout individu, qui participe à l’élaboration de standards pour Internet. L’IETF produit la plupart des nouveaux standards d’Internet. Source : Wikipedia. Une vue plus précise de l’IETF sur le site de l’ISOC France. L’IETF est dirigé par l’IESG, qui lui n’est pas un groupe informel. Pour une vue plus large des principaux organismes de l’Internet, lire A Concise Guide to the Major Internet Bodies / Alex Simonelis, Ubiquity vol. 6 n° 5 (15-22 février 2005). Ubiquity est une revue scientifique de la très réputée société savante américaine Association for Computing Machinery (ACM).).

[2] L’ITTIG est le LII italien.

[3] Sur les LII et le mouvement de diffusion libre du droit, voir notre article Les Legal Informations Institutes (LII) ou le mouvement pour la diffusion libre du droit.

[4] Cf les éléments et .

Commentaires

Aucun commentaire

Laisser un commentaire

Emmanuel Barthe

Mots-clés de l'article

A lire aussi

Twitter